Depends on the version you are in. If 2015 yes. Prior to that no.

Tom, yes i am using version 2015.

Tom,
Can you give me instructions on how to copy the info into General Ledger?

There is actually a script that will do that. You might need to contact The Whiz Kid aka Elliott on how to implement

retVal = 0

strJrnlNo = ""
strPostDate = ""

retVal = oUIObj.GetValue("ML_JournalNo$", strJrnlNo)
retVal = oUIObj.GetValue("ML_PostingDate$", strPostDate)


strPostDate = Mid(strPostDate, 1, 4) & "-" & Mid(strPostDate, 5, 2) & "-" & Mid(strPostDate, 7, 2)

DIM strSQLCmnd

MAS_Scr_Dbg = 0

'Initiate the Sage100 ERP connection
sConnection = "DSN=SOTAMAS90;UID=;COMPANY=ABC;PWD=" ' NOTE this assumes no security, with ABC. UID and PWD need to be supplied if security is enabled.

Set oConnection = CreateObject("ADODB.Connection")

'AddObject "oConnection", oConnection

oConnection.Open sConnection

Set rsGL = CreateObject("ADODB.Recordset")

strSrcJournal = Ucase(MID(strJrnlNo, 1, 2))

'Get postings from journal
strSQLCmd = "SELECT AccountKey, DebitAmount, CreditAmount"
strSQLCmd = strSQLCmd & " FROM GL_DetailPosting Where SourceJournal = " & Chr(39) & strSrcJournal & Chr(39)
strSQLCmd = strSQLCmd & " AND JournalRegisterNo = " & Chr(39) & Mid(strJrnlNo, 4) & Chr(39) & " AND PostingDate = "
strSQLCmd = strSQLCmd & " {d" & Chr(39) & strPostDate & Chr(39) & "}"

retVal = oScript.DebugPrint("SQL Command: " & strSQLCmd)

' Retrieve GL transactions to reverse


With rsGL
.ActiveConnection = oConnection
.Source = strSQLcmd
.CursorType = 0 'forward only
.LockType = 1 'read ony
.Open 'Open executes the query
End With


rsGL.MoveFirst

if Not(rsGL.EOF or rsGL.BOF) then

'found something to reverse
Dim oGJ
Dim oGJLines

Set oGJ = oScript.AsObject(oSession.GetObject("GL_GeneralJournal_bus"))
Set oGJLines = oScript.AsObject(oGJ.Lines)

retVal = oGJ.SetKeyValue("SourceJournal$", strSrcJournal)

entNo = "" ' let script know that return value on next statement is a string
retVal = oGJ.GetNextEntryNo(strSrcJournal, entNo) ' get next entry number for source journal
retVal = oGJ.SetKeyValue("EntryNo$",entNo)
retVal = oGJ.SetKey()


retVal = oGJ.SetValue("JournalComment$", "Reversal of entry: " & Ucase(strJrnlNo))

acct = ""
debit = 0
credit = 0

rsGL.MoveFirst

Do While Not rsGL.EOF

acct = rsGL("AccountKey")
debit = CDbl(rsGL("DebitAmount")) ' Convert amount to a double type numeric
credit = CDbl(rsGL("CreditAmount"))

retVal = oGJLines.AddLine()
retVal = oGJLines.SetValue("AccountKey$", acct)

If debit <> 0 Then
retVal = oGJLines.SetValue("DebitAmount", debit * -1)
End If

If credit <> 0 Then
retVal = oGJLines.SetValue("CreditAmount", credit * -1)
End If

retVal = oGJLines.Write()
rsGL.MoveNext
Loop

retVal = oGJ.Write()

End If

retVal = oSession.AsObject(oSession.UI).MessageBox("", "Reversal complete. Review in General Journal Entry prior to updating.") ' use UI object messagebox as best practice since VB msgbox will not work in Sage 100 ERP Advanced/Premium, the dialog box would be sitting on the server.