After a couple of hours of research I think I am getting closer, but I am just not very familiar with the Sage object model...

I assume I am needing to use GetObject() to return the data table I need for AR. Also figured out that I should be using Value$ instead of Text$ for the property name. I feel this may be close, but it still doesn't work:

Dim oARCustomer
Set oARCustomer = oSession.AsObject(oSession.GetObject("AR_Customer_bus"))
oARCustomer.SetKeyValue "ARDivisionNo$", SO_SalesOrder_bus_ARDivisionNo
oARCustomer.SetKeyValue "CustomerNo$", SO_SalesOrder_bus_CustomerNo
oARCustomer.Find()

Dim BTName, BTAddr1, BTAddr2, BTAddr3, BTZip, BTCity, BTState, BTCountry
oARCustomer.GetValue "CustomerName", BTName
oARCustomer.GetValue "AddressLine1", BTAddr1
oARCustomer.GetValue "AddressLine2", BTAddr2

'This should be re-populating the fields in the UI, but instead they get a value of '0'
oUIObj.SetControlProperty "BILLTONAME", "Value$", BTName & " (Test)"
oUIObj.SetControlProperty "BILLTOADDRESS1", "Value$", BTAddr1
oUIObj.SetControlProperty "BILLTOADDRESS2", "Value$", BTAddr2

Are you trying to correct multiple orders because if you are, you would probably be better off running a VI job on SO_SalesOrderHeader with ODBC as the source, point it to the SOTAMAS90 DSN, you can optionally save the login credentials or have the user login every time they run it.  You could then link SO_SalesOrderHeader and AR_Customer and have a WHERE clause so it only selects records where there is a discrepancy among the address fields.  This way you could just run it periodically to update all orders.  There are pros and cons to this approach.  The biggest con is probably the fact that whoever runs the job will be the user who gets tracked as the user to update the records last.  The pro is that you don't have to do it on an order by order basis or have someone forget to update an order with the button script.

If you are going to go the button script route, you should use the existing AR_Customer_Svc child handle.  You should not be use *_bus objects for read only activities, use the *_svc objects for this.

When using a child handle object, I find it best to use the business object's ReadAdditional method and pass the child source name to it to force it to reread the child source record to make sure you get the expected values.  Depending on whether or not you are using National Accounts, and the order in question has a different bill to customer, then you will want to use either the "CustomerNo" or "BillToCustomerNo" child handle.

sBillToCustomerNo = "" : oBusObj.GetValue "BillToCustomerNo$", sBillToCustomerNo
If sBillToCustomerNo <> "" Then
	oBusObj.ReadAdditional "BillToCustomerNo"
	Set oAR_Customer_Svc = oSession.AsObject(oBusObj.GetChildHandle("BillToCustomerNo"))
Else
	oBusObj.ReadAdditional "CustomerNo"
	Set oAR_Customer_Svc = oSession.AsObject(oBusObj.GetChildHandle("CustomerNo"))
End If
sAddressLine1 = "" : oAR_Customer_Svc.GetValue "AddressLine1$", sAddressLine1
oUIObj.InvokeChange "BillToAddress1", sAddressLine1
Set oAR_Customer_Svc = Nothing

When the UI is present, like it is in a button script, you can use oUIObj.InvokeChange which should be used instead of SetControlProperty.  This makes sure the appropriate logic takes place.  When the UI is not present, you should be using oBusObj.SetValue.

This works great, and thank you for explaining bus vs svc usage!